# Deploy a Token

By [boater](https://paragraph.com/@boater) · 2023-02-11

---

1、open this website with chrome.

2、accept and then click next, done.

![](https://storage.googleapis.com/papyrus_images/a946fefa81d1f6605d0c683324194102aa032c68d8099cde72a9b284962d64ad.png)

3、click the small button（create new file),name new file with ERC20.sol

![](https://storage.googleapis.com/papyrus_images/3e6fdd0b6f3a435012d067ddd0ef507a4acc93cb5f2e66260607ca80c227cbfa.png)

You can get:

![](https://storage.googleapis.com/papyrus_images/8e448b70eb739f150cf8d541ef64292794a7fc0390d7233f759714a52b709f10.png)

4、copy this code to ERC20.sol

    // SPDX-License-Identifier: MIT
    // WTF Solidity by 0xAA
    
    pragma solidity ^0.8.4;
    
    interface IERC20 {
        /**
         * @dev 释放条件：当 `value` 单位的货币从账户 (`from`) 转账到另一账户 (`to`)时.
         */
        event Transfer(address indexed from, address indexed to, uint256 value);
    
        /**
         * @dev 释放条件：当 `value` 单位的货币从账户 (`owner`) 授权给另一账户 (`spender`)时.
         */
        event Approval(address indexed owner, address indexed spender, uint256 value);
    
        /**
         * @dev 返回代币总供给.
         */
        function totalSupply() external view returns (uint256);
    
        /**
         * @dev 返回账户`account`所持有的代币数.
         */
        function balanceOf(address account) external view returns (uint256);
    
        /**
         * @dev 转账 `amount` 单位代币，从调用者账户到另一账户 `to`.
         *
         * 如果成功，返回 `true`.
         *
         * 释放 {Transfer} 事件.
         */
        function transfer(address to, uint256 amount) external returns (bool);
    
        /**
         * @dev 返回`owner`账户授权给`spender`账户的额度，默认为0。
         *
         * 当{approve} 或 {transferFrom} 被调用时，`allowance`会改变.
         */
        function allowance(address owner, address spender) external view returns (uint256);
    
        /**
         * @dev 调用者账户给`spender`账户授权 `amount`数量代币。
         *
         * 如果成功，返回 `true`.
         *
         * 释放 {Approval} 事件.
         */
        function approve(address spender, uint256 amount) external returns (bool);
    
        /**
         * @dev 通过授权机制，从`from`账户向`to`账户转账`amount`数量代币。转账的部分会从调用者的`allowance`中扣除。
         *
         * 如果成功，返回 `true`.
         *
         * 释放 {Transfer} 事件.
         */
        function transferFrom(
            address from,
            address to,
            uint256 amount
        ) external returns (bool);
    }
    
    contract ERC20 is IERC20 {
    
        mapping(address => uint256) public override balanceOf;
    
        mapping(address => mapping(address => uint256)) public override allowance;
    
        uint256 public override totalSupply;   // 代币总供给
    
        string public name;   // 名称
        string public symbol;  // 符号
        
        uint8 public decimals = 18; // 小数位数
        address public owner;
    
        // @dev 在合约部署的时候实现合约名称和符号
        constructor(string memory name_, string memory symbol_){
            name = name_;
            symbol = symbol_;
            owner = msg.sender;
        }
    
        // @dev 实现`transfer`函数，代币转账逻辑
        function transfer(address recipient, uint amount) external override returns (bool) {
            balanceOf[msg.sender] -= amount;
            balanceOf[recipient] += amount;
            emit Transfer(msg.sender, recipient, amount);
            return true;
        }
    
        // @dev 实现 `approve` 函数, 代币授权逻辑
        function approve(address spender, uint amount) external override returns (bool) {
            allowance[msg.sender][spender] = amount;
            emit Approval(msg.sender, spender, amount);
            return true;
        }
    
        // @dev 实现`transferFrom`函数，代币授权转账逻辑
        function transferFrom(
            address sender,
            address recipient,
            uint amount
        ) external override returns (bool) {
            allowance[sender][msg.sender] -= amount;
            balanceOf[sender] -= amount;
            balanceOf[recipient] += amount;
            emit Transfer(sender, recipient, amount);
            return true;
        }
    
        // @dev 铸造代币，从 `0` 地址转账给 调用者地址
        function mint(uint amount) external {
            require(owner == msg.sender);
            balanceOf[msg.sender] += amount;
            totalSupply += amount;
            emit Transfer(address(0), msg.sender, amount);
        }
    
        // @dev 销毁代币，从 调用者地址 转账给  `0` 地址
        function burn(uint amount) external {
            balanceOf[msg.sender] -= amount;
            totalSupply -= amount;
            emit Transfer(msg.sender, address(0), amount);
        }
    
    }
    

5、click the red “1” and then click “2” to compile the file

![](https://storage.googleapis.com/papyrus_images/10dfc26cc61671a0ba2ad854b2b7e63db1ec204db70463de316195129ff98bb4.png)

6、Turn the metamsk network to scroll alpha testnet, click “red 1”，

then choose injected provider-metamsk,

type name\_ and symbol\_ with strings, such as tobber, tob.

click the “transact”

![](https://storage.googleapis.com/papyrus_images/dcaf723e166a38fe8c0176c04ec44c26a5f13e3045c873681db53c441f62947c.png)

7、type 18000000000000000000000000 to “mint” function and click “transact”

copy the address of our token address （the red circle）

![](https://storage.googleapis.com/papyrus_images/3da780bc367c7e6aba673bda76d310ba7eca18765477eec204c03f27a097db66.png)

8、 add a pool on uniswap

![](https://storage.googleapis.com/papyrus_images/dda59d9b8433406c20557558eb209169bfadd2eeea3b802cef623aefe528b3f7.png)

And then everyone can buy your token via uniswap.

---

*Originally published on [boater](https://paragraph.com/@boater/deploy-a-token)*